§ ITPOW >> 文档 >> ASP >> ASP应用

搜索中的谓词处理（连载一）

作者：chilleen 来源：ITPOW 日期：2006-1-15

来源：ITPOW（www.itpow.com）

定义
在搜索词中空格代表和，加号代表或，减号代表否，忽略大小写与中英文符号区别，不考虑括号和引号。

当我们从客户端获取搜索词后，要将空格替换成SQL语句认为的and，加号替换成or，减号替换成not，如果用户的输入合乎语法，那么就挺简单的，直接替换就行了，可是用户的输入往往不合乎语法，这就需要“规范搜索词”。

搜索词不规范（不合乎语法）不外乎两种情况：两端出现谓词、连续出现谓词。比如“+中国四川”，这个搜索词中，第一个谓词“+”就是不合法的。再比如“中国 +-+四川”，中间连续出现了四个谓词，只能取一个，假设我们只认最先出现的那个。

开始我的想法是一遍实现“规范搜索词”，可是不便于理解，所以我分了两步走，第一步去除搜索词两端的谓词，第二步处理相邻的谓词。

看下面的示例（VBScript语言），程序将“-中国 +农业-发展+ +”修正为了“中国农业-发展”

<html>

<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>搜索中的谓词处理</title>
</head>

<body>

<div>
<a href="http://www.itpow.com/" target="_blank">ITPOW www.itpow.com 专业探讨【ASP、JavaScript、XHTML+CSS、SQL Server】</a>
<hr>
</div>

<script type="text/vbscript" language="vbscript">
<!--
dim key
key = "-中国 +农业-发展+  +"

'将输入的符号转换成谓词并返回
function GetPredicate(c)
    if StrComp(c, " ", 1) = 0 then
        GetPredicate = "AND"
    elseif StrComp(c, "+", 1) = 0 then
        GetPredicate = "OR"
    elseif StrComp(c, "-", 1) = 0 then
        GetPredicate = "NOT"
    else
        GetPredicate = ""
    end if
end function

'去除字符串两端的谓词并返回
function TrimPredicate(str)
    dim startPos
    for startPos=1 to Len(str)
        if GetPredicate(Mid(str, startPos, 1)) = "" then
            exit for
        end if
    next

    dim endPos
    for endPos=Len(str) to startPos step -1
        if GetPredicate(Mid(str, endPos, 1)) = "" then
            exit for
        end if
    next
    
    TrimPredicate = Mid(str, startPos, endPos-startPos+1)
end function

'滤去相邻的谓词
function CollPredicate(str)
    dim i, c, prevPredicate, predicate
    c = ""
    prevPredicate = ""
    predicate = ""
    for i=1 to Len(str)
        c = Mid(str, i, 1)
        predicate = GetPredicate(c)
        if predicate = "" then
            CollPredicate = CollPredicate & c
            prevPredicate = predicate
        elseif prevPredicate = "" then
            CollPredicate = CollPredicate & c
            prevPredicate = predicate
        end if
    next
end function

key = TrimPredicate(key)
key = CollPredicate(key)
document.write(key)
-->
</script>
</body>

</html>

[Ctrl+A 全部选择提示：你可先修改部分代码，再按运行]

连载一结束

电邮：cftea@126.com