搜索中的谓词处理（连载二）

来源：千一网络（www.cftea.com）

在处理相邻谓词时，前面的方法是取第一个谓词，其实不是最好的，比如"农业 + 工业"，用户的目的很可能是要搜索“农业”或“工业”，“+”两边的空格完全是出于一种单词间的间隔，并不是它要将空格作为谓词，所以下面的程序作了些改进，降低了空格的级别，当它与加号或减号相遇时，取加号或减号。

示例（VBScript语言）

<html>

<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>搜索中的谓词处理</title>
</head>

<body>

<div>
<a href="http://www.cftea.com/" target="_blank">千一网络 www.cftea.com 专业探讨【ASP、JavaScript、XHTML+CSS、SQL Server】</a>
<hr>
</div>

<script type="text/vbscript" language="vbscript">
<!--
dim key
key = "-中国 +农业-发展+  +"

'将输入的符号转换成谓词并返回
function GetPredicate(c)
    if StrComp(c, " ", 1) = 0 then
        GetPredicate = "AND"
    elseif StrComp(c, "+", 1) = 0 then
        GetPredicate = "OR"
    elseif StrComp(c, "-", 1) = 0 then
        GetPredicate = "NOT"
    else
        GetPredicate = ""
    end if
end function

'去除字符串两端的谓词并返回
function TrimPredicate(str)
    dim startPos
    for startPos=1 to Len(str)
        if GetPredicate(Mid(str, startPos, 1)) = "" then
            exit for
        end if
    next

    dim endPos
    for endPos=Len(str) to startPos step -1
        if GetPredicate(Mid(str, endPos, 1)) = "" then
            exit for
        end if
    next
    
    TrimPredicate = Mid(str, startPos, endPos-startPos+1)
end function

'滤去相邻的谓词
function CollPredicate(str)
    dim i, prevPredicateChr, c, prevPredicate, predicate
    prevPredicateChr = ""
    c = ""
    prevPredicate = ""
    predicate = ""
    for i=1 to Len(str)
        c = Mid(str, i, 1)
        predicate = GetPredicate(c)
        if predicate = "" then
            CollPredicate = CollPredicate & prevPredicateChr & c
            prevPredicateChr = ""
            prevPredicate = ""
        elseif prevPredicate="" or prevPredicate="AND" then
            prevPredicateChr = c
            prevPredicate = predicate
        end if
    next
end function

key = TrimPredicate(key)
key = CollPredicate(key)
document.write(key)
-->
</script>
</body>

</html>

[Ctrl+A 全部选择提示：你可先修改部分代码，再按运行]

连载二结束

ASP.NET 中的 AJAX	ASP.NET 画图全接触	ASP.NET 与 XML	声明式数据绑定	ASP.NET 网页抓取
C# 基础	C# 类教程	C# 加密	ASP.NET 成员资格	非“自动化”处理 Excel
QuickAjax	Ajax	完美的语法高亮器	Silverlight	Popfly